@echo off
setlocal
REM Codefutura Remote - instalacion en Windows (usa el cliente oficial RustDesk 1.5.1)
net session >nul 2>&1
if errorlevel 1 (
  echo Haga clic derecho en este archivo y elija "Ejecutar como administrador".
  pause
  exit /b 1
)
if not exist C:\Temp md C:\Temp
cd /d C:\Temp
echo Descargando...
curl -L -o codefutura-remote-setup.exe https://remote.codefutura.com/descargar/files/rustdesk-1.5.1-x86_64.exe
if errorlevel 1 (
  echo No se pudo descargar. Verifique su conexion a internet.
  pause
  exit /b 1
)
echo Instalando...
codefutura-remote-setup.exe --silent-install
timeout /t 20 /nobreak >nul
cd /d "C:\Program Files\RustDesk"
rustdesk.exe --install-service
timeout /t 20 /nobreak >nul
rustdesk.exe --config 9JyNxETMyoTbvNmLhJXd0VnZlR2bj5SZ09WblJnI6ISehxWZyJCLiIiOikGchJCLi0TSMhGR5AXStlVaShDdlNEbxA1dzRUTuFTWyFkQxEFTjJESTRmV51UZRdkNiojI5V2aiwiIt92YuEmc1RXdmVGZvNmLlR3btVmciojI0N3boJye
timeout /t 5 /nobreak >nul
for /f "delims=" %%i in ('rustdesk.exe --get-id ^| more') do set RID=%%i
echo.
echo ================================================
echo  Instalacion terminada.
echo  Su ID de Codefutura Remote es: %RID%
echo  Comparta este ID con su tecnico.
echo ================================================
pause